{The code in madonna}
Method STIFF
dT=1e-4
DTMAX=0.05
STARTTIME=-9600
STOPTIME=2200
TOLERANCE=1E-7
DTOUT=1
{MS2 FRAP Model based on Darzacq et al. -> by Yehuda Brody}
{ equations }
d/dt(Elongation) =Kin - Pout - Pbi +Pbo
d/dt(Pause) = Pbi - Pbo
Pout = Kout*Elongation
Pbi = Kpi*Elongation
Pbo = Kpo*Pause
INIT Elongation = 0
INIT Pause=0
{Traced molecule using GFP fused protein }
d/dt(GProt) =GPin - GPout -GPbi +GPbo - Pbleach
d/dt(GBind) = GPbi - GPbo - PbleachBind
GPin =Kin
GPout = Pout * (GProt/(Elongation + epsilon))
GPbi = Pbi * (GProt/(Elongation+ epsilon))
GPbo = Pbo * (GBind/(Pause +epsilon))
Pbleach = IF TIME >= -0.42 AND TIME < 0 THEN kbleach * GProt ELSE IF TIME>0 THEN kbleach2*GProt ELSE 0
PbleachBind = IF TIME >= -0.42 AND TIME < 0 THEN kbleach * GBind ELSE IF TIME>0 THEN kbleach2*GBind ELSE 0
INIT Bleached = 0
d/dt(Bleached) = Pbleach
INIT BindBleached = 0
d/dt(BindBleached) = PbleachBind
INIT GBind = 0
INIT GProt = 0
epsilon = 1E-10
kbleach =2.8
kbleach2 =0
Kpi = 0.0067
Kpo = 0.0015
Kout = 0.0112
Kin =70
LookData = Gprot+GBind
SSBind =(-Kin / ( Kpo-( (Kout*Kpo+Kpi*Kpo )/ (Kpi) ) ) )
SSProt = SSBind*(Kpo/Kpi )
LookProt = GProt/SSProt
LookBind = GBind/SSBind
nLookData = (Gprot+GBind)/ (SSBind + SSProt)
{need to curve fit your data with nLookData}